|
Apprendre Maple Site dédié au logiciel de calcul formel Maple
|
Voir le sujet précédent :: Voir le sujet suivant |
Auteur |
Message |
Jean-Michel Invité
|
Posté le: 06 Sep 2003 8:14 Sujet du message: Cercle des 9 points |
|
|
Comment avec MAPLE tracer le cercle d'Euler ou cercle des 9 points d'un triangle ABC? |
|
Revenir en haut de page |
|
|
Invité
|
Posté le: 06 Sep 2003 8:32 Sujet du message: |
|
|
> with(geometry):
> triangle(T, [point(A,0,0), point(B,2,0), point(C,1,3)]):
> EulerCircle(EC,T,'centername'=O):
> detail(EC);
assume that the names of the horizontal and vertical axes are _x and _y, respectively
name of the object: EC
form of the object: circle2d
name of the center: O
coordinates of the center: [1, 5/6]
radius of the circle: 1/36*25^(1/2)*36^(1/2)
equation of the circle: _x^2+1+_y^2-2*_x-5/3*_y = 0
Pour tracer ABC et le cercle d'Euler:
> draw({T,EC},printtext=true);
|
|
Revenir en haut de page |
|
|
ALS
Inscrit le: 11 Sep 2006 Messages: 647
|
Posté le: 06 Sep 2003 11:34 Sujet du message: |
|
|
On peut même faire mieux en faisant démontrer ce théorème à MAPLE:
Théorème: Cercle d'Euler ou cercle des 9 points
Soient:
Un triangle ABC quelconque d'orthocentre H.
M1, M2, M3 les milieux des côtés BC, CA, AB.
H1, H2, H3 les pieds des hauteurs du triangle ABC issues de A,B,C respectivement.
N1, N2, N3 les milieux des segments AH, BH, CH.
Alors les 9 points M1, M2, M3, H1, H2, H3, N1, N2, N3 sont sur un cercle C2 dont le centre N est le milieu du segment joignant l'orthocentre H au centre O du cercle circonscrit C1 au triangle ABC, et dont le rayon est la moitié de celui du cercle C1.
Définition: Le cercle C2 est appelé Cercle d'Euler ou cercle des 9 points du triangle ABC.
> with(geometry):
> # Definition du triangle T=(ABC)
> triangle(T,[point(A,0,0),point(B,3,5),point(C,7,0)]):
> # milieux des segments BC,CA,AB
> midpoint(M1,B,C): midpoint(M2,C,A): midpoint(M3,A,B):
> # orthocentre et centre O du cercle circonscrit à T
> orthocenter(H,T): circumcircle(C1,T,'centername'=O):
> # hauteurs issues des sommets A,B,C
> altitude(AH1,A,T,H1): altitude(BH2,B,T,H2):
> altitude(CH3,C,T,H3):
> # Definition des points N1, N2, N3, du point N et du cercle C2
> midpoint(N1,A,H): midpoint(N2,B,H): midpoint(N3,C,H):
> circle(C2,[midpoint(N,H,O),1/2*radius(C1)]):
> # M1, M2, M3, H1, H2, H3, N1, N2, N3 sont-ils sur le cercle C2?
> IsOnCircle(M1,C2); IsOnCircle(M2,C2); IsOnCircle(M3,C2);
> IsOnCircle(H1,C2); IsOnCircle(H2,C2); IsOnCircle(H3,C2);
> IsOnCircle(N1,C2); IsOnCircle(N2,C2); IsOnCircle(N3,C2);
> # tracé de la figure:
> draw([C2(filled=true,color='COLOR'(RGB,1.00000000,1.00000000,.8000000000)),
> C1(filled=true,color=green),T(style=line,color=blue),N,M1,M2,M3,H1,H2,H3,N1,N2,N3,H],
> style=point,symbol=diamond,axes=none,printtext=true);
true
true
true
true
true
true
true
true
true
Ce qui donne la figure suivante:
http://alamanya.free.fr/forum/images/cercleeuler.gif |
|
Revenir en haut de page |
|
|
|
|
Vous ne pouvez pas poster de nouveaux sujets dans ce forum Vous ne pouvez pas répondre aux sujets dans ce forum Vous ne pouvez pas éditer vos messages dans ce forum Vous ne pouvez pas supprimer vos messages dans ce forum Vous ne pouvez pas voter dans les sondages de ce forum
|
Développé par phpBB © 2001, 2006 phpBB Group
Traduction par : phpBB-fr.com
Apprendre Maple - ©
- Alain Le Stang - Navigation optimisée pour une résolution 1024 x 768.
|