prof_simplet
Inscrit le: 12 Sep 2006 Messages: 86
|
Posté le: 06 Juin 2012 13:29 Sujet du message: Cercle d'Euler |
|
|
Bonjour à tous,
Pour ceux que ça intéresse, voici un exercice sur le cercle d'Euler ou cercle des 9 points.
Soient: Un triangle ABC d'orthocentre H,
M1, M2, M3 les milieux des côtés BC, CA, AB,
H1, H2, H3 les pieds des hauteurs du triangle ABC issues de A,B,C respectivement,
N1, N2, N3 les milieux des segments AH, BH, CH.
Alors les 9 points M1, M2, M3, H1, H2, H3, N1, N2, N3 sont sur un cercle C2 dont le centre N est le milieu du segment joignant l'orthocentre H au centre O du cercle circonscrit C1 au triangle ABC, et dont le rayon est la moitié de celui du cercle C1.
Code: |
> with(geometry):
> # Definition du triangle T=(ABC)
> triangle(T,[point(A,-1,4),point(B,1,9),point(C,7,-1)]):
>
> # milieux des segments BC,CA,AB
> midpoint(M1,B,C): midpoint(M2,C,A): midpoint(M3,A,B):
>
> # orthocentre et centre O du cercle circonscrit à T
> orthocenter(H,T): circumcircle(C1,T,'centername'=O):
>
> # hauteurs issues des sommets A,B,C et H1,H2,H3
> altitude(AH1,A,T,H1): altitude(BH2,B,T,H2): altitude(CH3,C,T,H3):
>
> # Definition des points N1, N2, N3, du point N et du cercle C2
> midpoint(N1,A,H): midpoint(N2,B,H): midpoint(N3,C,H):
> circle(C2,[midpoint(N,H,O),1/2*radius(C1)]):
>
> # M1, M2, M3, H1, H2, H3, N1, N2, N3 sont-ils sur le cercle C2?
> IsOnCircle(M1,C2); IsOnCircle(M2,C2); IsOnCircle(M3,C2);
> IsOnCircle(H1,C2); IsOnCircle(H2,C2); IsOnCircle(H3,C2);
> IsOnCircle(N1,C2); IsOnCircle(N2,C2); IsOnCircle(N3,C2);
true
true
true
true
true
true
true
true
true
> # tracé de la figure:
> draw([C2(filled=true,color=white),
> C1(filled=true,color=white),T(style=line,color=black),N,M1,M2,M3,H1,H2,H3,N1,N2,N3,H],
> style=point,symbol=diamond,axes=none,printtext=true);
|
|
|