Apprendre Maple

[Invité]

Comment écrire en MAPLE un programme permettant de remplir un tableau carré n x n en "colimaçon"
à l'aide des entiers successifs de 1 à n^2 ?
Exemple, pour n=5 on doit obtenir :
> colimacon(5);

[1 16 15 14 13]
[2 17 24 23 12]
[3 18 25 22 11]
[4 19 20 21 10]
[5 6 7 8 9]

[ALS]

On code les déplacements dans le tableau:
v=1(vertical vers le bas) h=1 (horizontal vers la droite)
v=-1(vertical vers le haut) h=-1(horizontal vers la gauche)
v=0 (déplacement horizontal en cours) h=0 (déplacement vertical en cours)

Les variables L,c,k désignent respectivement l'indice de ligne , l'indice de colonne , et le nombre
entier à mettre dans T[L,c]

> colimacon:=proc(n::posint)
> local i,j,k,L,c,v,h,T;
> T:=array(1..n,1..n):
> for i to n do
> for j to n do
> T[i,j]:=0:# on initialise le tableau T à la valeur 0
> end do
> end do:
> L:=1:c:=1:k:=1:v:=1:h:=0:T[1,1]:=1: # valeurs initiales en position (1,1)
> while k<n*n do
> if h=0 then # déplacement vertical
>
> # on teste la case suivante : si elle est dans les limites 1..n et n'a pas déjà été traitée , on lui affecte la valeur suivante de k :
>
> while 0<L+v and L+v<=n and T[L+v,c]=0 do
> L:=L+v:k:=k+1:T[L,c]:=k:
> end do:
> h:=v:v:=0: # changement de sens du déplacement
>
> else # déplacement horizontal
>
> #on teste la case suivante : si elle est dans les limites 1..n et n'a pas déjà été traitée , on lui affecte la valeur suivante de k :
>
> while 0<c+h and c+h<=n and T[L,c+h]=0 do
> c:=c+h:k:=k+1:T[L,c]:=k:
> end do:
> v:=-h:h:=0: # changement de sens du déplacement
> end if;
> end do:
> print(T);
> end proc;

> colimacon(5);

[1 16 15 14 13]
[2 17 24 23 12]
[3 18 25 22 11]
[4 19 20 21 10]
[5 6 7 8 9]