Jeu de lettres "Motus"

Rechercher

Sommaire

Maplets

Ecran Maple

Téléchargement

Bibliographie

Liens

Page d'accueil Maplets << Page précédente Page suivante >>

Motus
© Alain Le Stang - "Apprendre Maple" - 2005
Sélectionner Edit/Execute/Worksheet ou cliquer le bouton !!! pour exécuter ce Maplet.

>	restart;

>	with(Maplets[Elements]): with(Maplets[Examples]): with(Maplets[Tools]): with(plots): with(plottools): with(StringTools):

Chemin à modifier
Les 12 fichiers suivants en liaison avec ce maplet doivent etre contenus dans un seul repertoire (de nom par exemple ici
"C:\\Maple\\maplets\\motus\\" ) :

motus.mw motus.maplet motus.gif comptepts.gif grille.gif pref.txt
motsenclair5.txt motsenclair6.txt motsenclair7.txt top5.txt top6.txt top7.txt

>	chemin:="C:\\Maple\\maplets\\motus\\":

Procédures:

RAZ_Grilles:=proc()
global grid,gridcolor;
grid:=[["","","","","","",""],["","","","","","",""],["","","","","","",""],
["","","","","","",""],["","","","","","",""],["","","","","","",""],
["","","","","","",""]]:
gridcolor:=[["b","b","b","b","b","b","b"],["b","b","b","b","b","b","b"],["b","b","b","b","b","b","b"],
["b","b","b","b","b","b","b"],["b","b","b","b","b","b","b"],["b","b","b","b","b","b","b"],
["b","b","b","b","b","b","b"]]:
end proc:

>	Sauve_Options :=proc() global pref,taille,niveau,m1,m2,m3; local f; f := fopen(pref,WRITE,TEXT); fprintf(f, "%d\n%d\n",taille,niveau); fprintf(f, "%d\n%d\n%d\n",m1[5],m2[5],m3[5]); fprintf(f, "%d\n%d\n%d\n",m1[6],m2[6],m3[6]); fprintf(f, "%d\n%d\n%d\n",m1[7],m2[7],m3[7]); fclose(f) end proc:

>	majRB:=proc(n::posint) global m1,m2,m3; Maplets:-Tools:-Set('RB4'('caption')=cat("Facile (",m1[n]," mots)")): Maplets:-Tools:-Set('RB5'('caption')=cat("Moyen (",m2[n]," mots)")): Maplets:-Tools:-Set('RB6'('caption')=cat("Difficile (",m3[n]," mots)")): meilleur_score(n); majscore(); end proc:

meilleur_score:=proc(n::posint)
global meilleur_joueur, meilleur;
local f;
f := fopen(fichscore[n],READ):
meilleur_joueur := FileTools[Text][ReadString](f):
meilleur := FileTools[Text][ReadInteger](f):
Maplets:-Tools:-Set('meilleurscore'('caption')= meilleur):
Maplets:-Tools:-Set('meilleurjoueur'('caption')= meilleur_joueur):
fclose(f)
end proc:

majscore:=proc()
global meilleur, total, nbmotstrouves, nbmots, meilleur_joueur;
Maplets:-Tools:-Set('score'('caption')=total):
Maplets:-Tools:-Set('trouves'('caption')=nbmotstrouves):
Maplets:-Tools:-Set('proposes'('caption')=nbmots):
if total > meilleur then meilleur := total: meilleur_joueur := "JOUEUR ACTUEL": end if;
Maplets:-Tools:-Set('meilleurscore'('caption')=meilleur):
Maplets:-Tools:-Set('meilleurjoueur'('caption')=meilleur_joueur):
end proc:

OptionsParDefaut:=proc()
global taille,niveau;
Maplets:-Tools:-Set('RB1'('value')=true):
Maplets:-Tools:-Set('RB2'('value')=false):
Maplets:-Tools:-Set('RB3'('value')=false):
Maplets:-Tools:-Set('RB4'('value')=true):
Maplets:-Tools:-Set('RB5'('value')=false):
Maplets:-Tools:-Set('RB6'('value')=false):
taille:=5 : niveau:=1:
majRB(5);
end proc:

Dessin de la cellule de la position (ligne,colonne) dans la grille n x n , avec une couleur RGB(a,b,c) a,b,c entre 0 et 1:

>	dessin:=proc(ligne::posint,colonne::posint,n::posint,a,b,c) local x,y; x:=colonne-1;y:=n-ligne; polygon([[x,y],[colonne,y],[colonne,y+1],[x,y+1]],color=COLOR(RGB,a,b,c)): end proc:

Dessin de la grille de jeu:

trace_grille:=proc()
global taille,grid,gridcolor;
local l,c,d,p,t,r,g,b;
d:=NULL:
for l to taille do
for c to taille do
   if gridcolor[c][l]="b" then r:=1:g:=1:b:=1
     elif gridcolor[c][l]="o" then r:=1:g:=0.6:b:=0
     elif gridcolor[c][l]="g" then r:=0.77:g:=0.77:b:=0.77
     else r:=1:g:=1:b:=0
   end if:
   d:=d,dessin(c,l,taille,r,g,b)
end do
end do;
p:=polygon([[0.2,taille],[0.2,taille+0.2],[taille+0.2,taille+0.2],[taille+0.2,0.2],[taille,0.2],
[taille,taille],[0.2,taille]],color=COLOR(RGB,.5,.5,.5)):
t:=NULL:
for l to taille do
for c to taille do
    t:=t,textplot([c-0.5,l-0.5,grid[taille-l+1][c]],font=[COURIER, BOLD,24+5*(7-taille)])
end do
end do:
display([d,p,t],axes=NONE);
end proc:

init_motus:=proc()
global nbmots,ligne,motsaisi,mot,gagne,taille,bonne,fichalpha,m3,level,niveau,grid,gridcolor;
local i,f,hasard,line,T;
T["1"]:=1:T["2"]:=2:T["3"]:=3:
nbmots := nbmots + 1: majscore():
ligne := 1: motsaisi:= "": gagne := false:
for i to taille do bonne[i]:= " " end do;
f:=fichalpha[taille]:hasard:=rand(m3[taille]):level:=4:
randomize():
while level>niveau do
i:=hasard()*13 :filepos(f,i):line:=readline(f):
mot:=substring(line,2..2+taille-1): # print(mot):
level:=T[substring(line,11)]
end do:
fclose(f):
RAZ_Grilles():
grid[1][1]:=substring(mot,1):
gridcolor[1][1]:="o":
Maplets:-Tools:-Set('Grille'=trace_grille()):
end proc:

ProposeMot:=proc()
global grid,gridcolor,bonne,ligne,taille,fin,mot,motsaisi,nbmots,nbmotstrouves;
local k,t;
t:=Maplets:-Tools:-Get('Saisie'('value')):
Maplets:-Tools:-Set('Saisie'('value')=UpperCase(t)):
motsaisi:=UpperCase(t);
if not fin then
analyse(motsaisi,mot);
if gagne then
    nbmotstrouves := 1 + nbmotstrouves: majscore():
    Maplets:-Tools:-Set('Saisie'('value')=""): motsaisi:="":
    if nbmots=10 then
       Alert(cat("Vous avez trouvé le mot """,mot,""".\n          Fin de partie."),title="Bravo!"):
       FinPartie();
    else
       Alert(cat("Vous avez trouvé le mot """,mot,""".\n          Jouez un autre mot."),title="Bravo!"):
       init_motus();
    end if;

else # mot non trouvé
   if ligne < taille then
     ligne := ligne + 1:
     for k from 0 to taille - 1 do
       if bonne[k + 1] <> " " then
         grid[ligne][k+1]:=bonne[k + 1]
       end if
     end do:
     Maplets:-Tools:-Set('Saisie'('value')=""): motsaisi:=""
   else # ligne=taille
      if nbmots = 10 then
        Alert(cat("Vous n'avez pas trouvé le mot """,mot,""".\n             Fin de partie."),title="Désolé!"):
        FinPartie();
      else
        Alert(cat("Vous n'avez pas trouvé le mot """,mot,""".\n          Jouez un autre mot."),title="Désolé!"):
        init_motus()
      end if;
      Maplets:-Tools:-Set('Saisie'('value')=""): motsaisi:="":
   end if;
end if;
end if
end proc:

analyse:=proc(x::string, m::string)
global gagne,ligne,level,total,bonne,taille,motsaisi,fin,grid,gridcolor;
local drapeaux,Flag,k,c;

drapeaux:=proc(x::string, m::string)
local k,l,X,M,R:
X:=convert(x,list); M:=convert(m,list);
R:=[-1$nops(M)];
for k to nops(X) do
if X[k]=M[k] then R[k]:=2: M[k]:=" ": X[k]:=" " fi
od;
for k to nops(X) do
if not member(X[k],M) then R[k]:=0: X[k]:=" " fi
od;
for k to nops(X) do
for l to nops(M) do
if X[k]<>" " and X[k]=M[l] then R[k]:=1: X[k]:=" ": M[l]:=" " fi
od;
od;
for k to nops(R) do
if R[k]=-1 then R[k]:=0 fi
od;
R
end proc:

if length(x)<>taille then
Alert(cat("Le mot proposé, """,motsaisi,""", n'a pas ",taille," lettres."),title="Mot erroné"):
return(NULL) end if;
for k to taille do
if not member(substring(x,k),["A","B","C","D","E","F","G","H","I","J","K","L","M","N","O","P","Q","R","S","T",
"U","V","W","X","Y","Z"]) then
Alert(cat("Le mot proposé, """,motsaisi,""", comprend un caractère non autorisé."),title="Mot erroné"):return(NULL) end if;
end do;
if trouve(x,taille) < 0 then
Alert(cat("Le mot proposé, """,motsaisi,""", n'est pas dans le dictionnaire.\n Vous devez jouer un autre mot."),title="Mot erroné"):return(NULL)
end if;

Flag:=drapeaux(x,m);
for k to length(x) do
c := substring(x,k):
if fin then
x:="": return(x)
end if;
if Flag[k]=2 then
if bonne[k] = " " then
bonne[k] := c: total := total + 2: majscore()
end if;
grid[ligne][k]:=c: gridcolor[ligne][k]:="o"
elif Flag[k]=1 then
grid[ligne][k]:=c: gridcolor[ligne][k]:="j":
total := total + 1: majscore()
else # Flag[k]=0
grid[ligne][k]:=c:
end if;
end do;
if x = m then
gagne := true:
total := total + (taille + 1 - ligne) * 5 + (level - 1) * 3: majscore()
end if;
Maplets:-Tools:-Set('Grille'=trace_grille()):
Maplets:-Tools:-Set('Saisie'('enabled')=true):
end proc:

trouve:=proc(x::string, n::posint)
global m3,fichalpha;
local r,xi,xj,f,i,j,k,line;
f:=fichalpha[n]:
i:=0: j:=m3[n]:
while j - i > 1 do
k:= floor((i+j)/2):filepos(f,k*13):line:=readline(f):
if LexOrder(substring(line,2..2+taille-1),x)=-1 then i:=k else j:=k end if
end do;
filepos(f,i*13): line:=readline(f): xi:=substring(line,2..2+taille-1):
filepos(f,j*13): line:=readline(f): xj:=substring(line,2..2+taille-1):
if x=xi then r:= i:
elif x=xj then r:=j:
else r:= -i end if;
fclose(f);
r
end proc:

commencer_jeu:=proc()
global fin, nbmots, nbmotstrouves, total;
fin:=false: nbmots := 0: nbmotstrouves := 0: total := 0:
Maplets:-Tools:-Set('Dictionnaire'('enabled')=false):
Maplets:-Tools:-Set('Scores'('enabled')=false):
Maplets:-Tools:-Set('Proposer'('enabled')=true):
Maplets:-Tools:-Set('Saisie'('enabled')=true):
Maplets:-Tools:-Set('Commencer'('enabled') = false):
init_motus()
end proc:

----------------------------- DicoMaplet ( Fenetre "Dictionnaire" ) ---------------------------------

>	Dict:=proc() Maplets[Display] (DicoMaplet); Sauve_Options() : Lire_Options() end proc:

>	majElements:=proc(n::posint) global m3,opt; Maplets:-Tools:-Set('nblettres'('caption')=cat("des mots de ",n," lettres")): Maplets:-Tools:-Set('Mess1'('caption')=cat(convert(m3[n],string)," mots")): Maplets:-Tools:-Set('Mess3'('caption')=" "): Efface1() : Efface2(): Efface3() end proc:

afficheMots:=proc(dep)
global m3,opt,qual;
local d,k,m,L;
d := abs(dep):
if d>=m3[opt]-20 then d:=m3[opt] - 22 end if;
L:=NULL:
for k from 0 to 21 do
m:= trouveMot(opt, d + k): L:=L,cat(m[1],qual[m[2]])
end do:
Maplets:-Tools:-Set('LB1'('itemlist')=[L]):
if d < m3[opt] - 21 then Maplets:-Tools:-Set('SL1'('value') = min(m3[opt],m3[opt]-d+1))
else Maplets:-Tools:-Set('SL1'('value') = 1) end if;
end proc:

afficheMotsFiltres:=proc(dep)
global listefiltree;
local d,k,n,L;
d:=dep: n:=nops(listefiltree):
if d=0 then d:=1 end if;
if d>n-21 then d:=n-21 end if;
L:=listefiltree[d..d+21]:
Maplets:-Tools:-Set('LB2'('itemlist')=L):
if d<n-21 then Maplets:-Tools:-Set('SL2'('value') = min(n,n-d+1))
else Maplets:-Tools:-Set('SL2'('value') = 1) end if;
end proc:

>	RechercheMot:=proc() global opt; local a,s,t; t := UpperCase(Maplets:-Tools:-Get('TFConsult'('value'))): a := trouve(convertir(t),opt): s := Maplets:-Tools:-Get('SL1'('upper')): if abs(a) > s then a := s end if; afficheMots(a) end proc:

FiltreMot:=proc()
global opt,m3,qual,listefiltree;
local a,c,i,j,m,y,k,mot,T,nbmots,dep,arret,lettre,nb;
T["1"]:=1:T["2"]:=2:T["3"]:=3: listefiltree:=NULL :
y:=convertir(Maplets:-Tools:-Get('TFFiltre'('value'))): nb := 0 :
for k to opt do
  if substring(y,k) <> " " then
     nb := nb + 1 : lettre[nb] := k
  end if
end do:
a := substring(y, 1):
if Ord(a)>=65 and Ord(a)<=89 then   # lettre de "A" à "Y"
     dep:= abs(trouve(cat(a,"      "),opt)):
     arret:= abs(trouve(cat(Char(Ord(a) + 1),"      "),opt))
elif Ord(a)=90 then                 # lettre "Z"
     dep:= abs(trouve("Z      ",opt)):
     arret:= m3[opt]-1
else
     dep:= 0: arret:= m3[opt]-1
end if;
nbmots := 0:
for j from dep to arret do
  m:=trouveMot(opt, j):
  if (lev1 < 4 and T[m[2]] = lev1) or (lev1 = 4) then
    mot := m[1]: c := 0:
    for i to nb do
      if substring(mot, lettre[i]) = substring(y, lettre[i]) then c := c + 1 end if
    end do:
    if c = nb then
      listefiltree:=listefiltree,cat(mot, qual[m[2]]):
      nbmots := nbmots + 1:
      Maplets:-Tools:-Set('Mess2'('caption') = cat(convert(nbmots,string), " mots"))
    end if
  end if
end do:
if nops([listefiltree])<22 then
    for i from nops([listefiltree])+1 to 22 do
        listefiltree:=listefiltree,"                                   " end do
    end if;
listefiltree:=[listefiltree]:
Maplets:-Tools:-Set('SL2'('upper') = nops(listefiltree)):
afficheMotsFiltres(1):
end proc:

>	convertir:=proc(x) local s,y,k; y:= "": for k to length(cat(x," ")) do s:=substring(x,k): if s="*" then y := cat(y, " ") elif (Ord(s)>=65 and Ord(s)<=95) or (Ord(s)>=97 and Ord(s)<=122) then y := cat(y,s) else y := cat(y," ") end if; end do: ajouteEspaces(UpperCase(y)) end proc:

>	ajouteEspaces:=proc(x::string) local i,y,z; y:=cat(x," "): z:="": for i to 7 do z:=cat(z,substring(y,i)) end do: z end proc:

>	AjouteMot:=proc() global opt,lev2; local t; t:=UpperCase(Maplets:-Tools:-Get('TFAjout'('value'))): if length(t)=opt then ajouter(ajouteEspaces(t), lev2) else Maplets:-Tools:-Set('Mess3'('caption')="Longueur incorrecte"): end if end proc:

ajouter:=proc(x::string, n::posint)
global opt,m1,m2,m3,fichalpha;
local L,line,a,f,g,i,j,t,y,p;
y := convertir(UpperCase(x)):
for p to opt do
  if Ord(substring(x,p)) < 65 or Ord(substring(x,p)) > 90 then
     Maplets:-Tools:-Set('Mess3'('caption')="Mot incorrect"): return(NULL)
  end if
end do:
t:= trouve(y,opt):
if t >= 0 then
     Maplets:-Tools:-Set('Mess3'('caption')="Mot déjà présent"): return(NULL)
else
    t:= abs(t): j:=m3[opt]-1:
    Maplets:-Tools:-Set('Mess3'('caption')="Ajout du mot en cours..."):
    if t <= 1 then
      a := 1
    elif t >= m3[opt] then
      a := 1 + j
    else
      a := 1 + t
    end if;

    L:=cat("""",y,""",",convert(n,string),Char(13),Char(0)): f:=fichalpha[opt]:
    for i from a to j do
       filepos(f,i*13): line:=readline(f): L:=L,line
    end do:
    fclose(f):
    L:=[L] :
    g:=fopen(fichalpha[opt],APPEND):
    for i from a to j+1 do
       filepos(g,i*13): fprintf(g,"%s\n",convert(L[i-a+1],string)):
    end do:
    closef(g):

    if n = 3 then m3[opt] := m3[opt] + 1 end if;
    if n = 2 then
        m2[opt] := m2[opt] + 1: m3[opt] := m3[opt] + 1
    end if;
    if n = 1 then
        m1[opt] := m1[opt] + 1: m2[opt] := m2[opt] + 1: m3[opt] := m3[opt] + 1
    end if;
    Maplets:-Tools:-Set('SL1'('upper')= m3[opt] - 21):
    Maplets:-Tools:-Set('Mess3'('caption')=""):
    Maplets:-Tools:-Set('Mess1'('caption')=cat(convert(m3[opt],string)," mots")):
end if
end proc:

>	trouveMot:=proc(n::posint, index::integer) global fichalpha,opt; local f,line; f:=fichalpha[n]: filepos(f,index*13): line:=readline(f): fclose(f); [substring(line,2..2+opt-1),substring(line,11)] end proc:

>	Efface1:=proc() Maplets:-Tools:-Set('TFConsult'('value')=""): afficheMots(0) end proc:

>	Efface2:=proc() local i,L; Maplets:-Tools:-Set('TFFiltre'('value')=""): L:=NULL: for i from 0 to 21 do L:=L," " end do: Maplets:-Tools:-Set('LB2'('itemlist')=[L]): Maplets:-Tools:-Set('Mess2'('caption')="Aucun mot"): end proc:

>	Efface3:=proc() Maplets:-Tools:-Set('TFAjout'('value')=""): end proc:

>	majListe1:=proc() global opt,m3; local t; t:=Maplets:-Tools:-Get('SL1'('value')): afficheMots(m3[opt]-t+1) end proc:

>	majListe2:=proc() global listefiltree; local t; t:=Maplets:-Tools:-Get('SL2'('value')): afficheMotsFiltres(nops(listefiltree)-t+1) end proc:

>	niv1:=proc(n) global lev1; lev1:=n end proc:

>	niv2:=proc(n) global lev2; lev2:=n end proc:

--------------------------- Top10Maplet ( Fenetre "Top10" des meilleurs scores ) ------------------------

>	Top10:=proc() Maplets[Display] (Top10Maplet) end proc:

>	EntreNom := Maplet( 'abnormalshutdown' = "FAIL", InputDialog['ID1']( "Saisissez votre prénom:", 'title' = "Entrez au Top10", 'onapprove' = Shutdown( ['ID1'] ), 'oncancel' = Shutdown( "FAIL" ) ) ):

>	Formate:=proc(x::string) local y,z,i; y:="": z:="": for i to length(x) do if substring(x,i)=" " or substring(x,i)="," then y:=cat(y,"_") else y:=cat(y,substring(x,i)) end if; end do: for i to length(y) do if i<=15 then z:=cat(z,substring(y,i)) end if end do: z end proc:

NomJoueur:=proc(x::posint,r)
global ordre,joueurs,scores,fichscore,taille,total,meilleur_joueur;
local f,i,s,t;
  s:=convert(cat(J,x),name):
  if r="FAIL" then t:="**** MOTUS ****" else t:=Formate(convert(op(r),string)) end if:
  Maplets:-Tools:-Set(s('caption')=UpperCase(t)):
  if x > 0 then
    joueurs[x] := UpperCase(t):
    if ordre = 1 then meilleur_joueur := joueurs[x] end if;
    f := fopen(fichscore[taille],WRITE):
    for i to 10 do
      fprintf(f, "%s\n%d\n",joueurs[i],scores[i])
    end do:
    fclose(f)
  end if:
end proc:

RazScores:=proc()
global total,taille,fichscore,meilleur_joueur,meilleur;
local r,i,j,f;
r:=Alert(cat("Vous voulez remettre à zéro tous les scores.\n Veuillez confirmer ou annuler."),title="Remise à zéro"):
if r=FAIL then return fi;
for i from 5 to 7 do
f := fopen(fichscore[i],WRITE):
for j to 10 do
fprintf(f, "%s\n%d\n","---------------",0)
end do:
fclose(f):
end do;
meilleur_joueur:="---------------": meilleur:=0;
total:=0:
majRB(taille);
end proc:

LireScores:=proc(n::posint)
global fichscore,joueurs,scores;
local i,f;
if n=5 then Maplets:-Tools:-Set('RBS1'('value')=true)
elif n=6 then Maplets:-Tools:-Set('RBS2'('value')=true)
else Maplets:-Tools:-Set('RBS3'('value')=true) end if;
f := fopen(fichscore[n],READ):
for i to 10 do
joueurs[i] := FileTools[Text][ReadString](f):
scores[i] := FileTools[Text][ReadInteger](f):
end do;
fclose(f):
end proc:

classer:=proc(i::integer)
global ordre,joueurs,scores;
local resultat,j,k,s,t,u;
ordre := -1:
if i > scores[10] then
  if i > scores[1] then
         for j from 10 to 2 by -1 do
          scores[j]:=scores[j-1]:joueurs[j]:=joueurs[j-1]
         end do;
         ordre := 1:
  else
    for j to 9 do
        if i > scores[j + 1] and i <= scores[j] then
             if j < 9 then
                  for k from 10 to j + 2 by -1 do
                    scores[k]:=scores[k-1]:joueurs[k]:=joueurs[k-1]
                  end do;
                  ordre := j + 1:
                  break
             else
                  ordre := 10
             end if
        end if
    end do
  end if
end if;
for j to 10 do
s:=convert(cat("S",j),name): t:=convert(cat("J",j),name):
Maplets:-Tools:-Set(t('caption')=cat(" ",joueurs[j]," ")):Maplets:-Tools:-Set(s('caption')=scores[j])
end do;
if ordre > 0 then
  scores[ordre]:= i:
  resultat := Maplets[Display](EntreNom);
  s:=convert(cat("S",ordre),name): t:=convert(cat("J",ordre),name):
  Maplets:-Tools:-Set(s('caption') = i):   Maplets:-Tools:-Set(t('caption')=""):
  NomJoueur(ordre,resultat)
end if;
end proc:

>	majAffichage:=proc(n::posint, t::integer) global total; LireScores(n): classer(t): total:=0: end proc:

---------------------------- MotusMaplet ( Fenetre de jeu "Motus") ---------------------

Initialisation des variables globales et démarrage du jeu:

nbmotstrouves:=0: meilleur:=0 : taille:=5 : niveau:=1 :
level:=0 : lev1:=4 : lev2:=1 : opt:=5: listefiltree:=[]:
total:=0: ordre:=0: mot:="": motsaisi:="": nbmots:=0: fin:=false: ligne:=0 :
gagne:=false: meilleur_joueur:="": qual["1"] := " (Facile)": qual["2"] := " (Moyen)": qual["3"] := " (Difficile)":
for k to 10 do joueurs[k]:="": scores[k]:=0 end do:
m1:=array(5..7): m2:=array(5..7): m3:=array(5..7):
for i from 5 to 7 do
fichalpha[i] := cat(chemin,"motsenclair",i,".txt"):
fichscore[i] := cat(chemin,"top",i,".txt")
end do:
pref:=cat(chemin,"pref.txt"):

Maplets[Display] (MotusMaplet);

haut de cette page